This code implements the depth-first search algorithm for finding connected components in a graph. After running it, boxes will have the same Tag value if they are in the same connected component.

Sub FindConnectedComponents()
	Dim setIds() As Integer
	Dim i As Integer, component As Integer

	ReDim setIds(0 To fcx.boxes.Count - 1)

	component = 0
	For i = 0 To fcx.boxes.Count - 1
		fcx.boxes(i).Tag = i
		setIds(i) = -1
	Next i

	For i = 0 To fcx.boxes.Count - 1
		If setIds(i) = -1 Then
			TraverseComponent setIds, i, component
			component = component + 1
		End If
	Next i

	For i = 0 To fcx.boxes.Count - 1
		fcx.boxes(i).Tag = setIds(i)
	Next i
End Sub

Sub TraverseComponent(setIds() As Integer, node As Integer, component As Integer)
	setIds(node) = component

	Dim a As arrow
	Dim child As box

	For Each a In fcx.boxes(node).OutgoingArrows
		Set child = a.DestinationBox
		If setIds(child.Tag) = -1 Then
			TraverseComponent setIds, child.Tag, component
		End If
	Next a

	For Each a In fcx.boxes(node).IncomingArrows
		Set child = a.OriginBox
		If setIds(child.Tag) = -1 Then
			TraverseComponent setIds, child.Tag, component
		End If
	Next a
End Sub

Private Sub Command1_Click()
	Dim colors(0 To 9)
	colors(0) = vbRed
	colors(1) = vbGreen
	colors(2) = vbBlue
	colors(3) = vbWhite
	colors(4) = vbYellow
	colors(5) = vbRed
	colors(6) = vbGreen
	colors(7) = vbBlue
	colors(8) = vbWhite
	colors(9) = vbYellow

	FindConnectedComponents

	Dim b As box
	For Each b In fcx.boxes
		b.FillColor = colors(b.Tag)
	Next b
End Sub
 

I hope that helps,
Stoyan

They are not a bug - the colors array contains each color twice. I've employed some copy and paste techniques here Anyway the code that colors the boxes is just for testing, and if the graph contains more than 10 connected components, you will get an index-out-of-bounds exception. So if you intend to do the same in production code, use the modulo operator to convert the component index (in box.Tag) to the color index. Should look something like this in Delphi:

colorIndex := box.Tag mod Length(colors);